// WoW Beta Spell/Skill Training Macro v1.1
//
//  Made by Anders "sarf" Kronquist, 2004
//   beta utility/stuff developer for WoW Forge, http://www.wowforge.net/
//
// Strictly for betatesting purposes. Do not use to get "über". :)
//
//
// Features :
//
//  Specify what skills/spells you want to train.
//

//
// Unimplemented features :
//
//  Wait for skill/spell cooldown (somewhat fixed by having spells done after skills)

//
// Setup instructions :
//  Change SetupSkills (skills are located on the current quick bar)
//  Change SetupSpells (spells are located on the quick bar "above" the skill bar)
//
//   Each number in the skill/spells refer to the slot number, 
//    counted from the left to the right, starting with one (1).
//
//  Setting up Skills/Spells consist of adding the number of the slot you want to train to the list.

include WoW_Beta_Macros.inc

Constants
	// how many loops should be run, if zero or less will do an infinite number of loops
	TrainingLoops = 100
	
	AbilityCounter = 0
	AbilityNumber = 0
End

Constructs
	SpellList=List
	SkillList=List
End


Procedure Wait100
	ProcessMessages
	Delay 100
	ProcessMessages
End

Procedure WaitForMana
	While $HasFullMana = 0
		call Wait100
	End
End

Procedure TrainAbility Using AbilityNumber, ShouldWaitForMana
	If $ShouldWaitForMana = 1
		call WaitForMana
	End
	call UseSlot $AbilityNumber
	If $ShouldWaitForMana = 1
		Delay 1 sec
	Else
		Delay 500
	End
End

Procedure TrainList Using AbilityList, ShouldWaitForMana
	SetConst AbilityCounter = 1
	ListCount $AbilityList, AbilityNumber
	While $AbilityCounter <= $AbilityNumber
		call TrainAbility $AbilityList[$AbilityCounter], $ShouldWaitForMana
		Delay 100
		Inc $AbilityCounter
	End
	call PutMouseInNeutralPosition
End

Procedure TrainSkills
	call TrainList SkillList, 0
End

Procedure TrainSpells
	call GoToNextQuickBar
	call TrainList SpellList, 1
	call GoToPreviousQuickBar
End


Procedure MainLoop
	call TrainSkills
	call TrainSpells
End

Procedure DoTrain
	If $TrainingLoops <= 0
		While $TrainingLoops <= 0
			call MainLoop
		End
	Else
		Loop $TrainingLoops
			call MainLoop
		End
	End
End

// change this to train the skills you want
Procedure SetupSkills
	//ListAdd SkillList, 1
End

// change this to train the spells you want
Procedure SetupSpells
	ListAdd SpellList, 2
End

call SetupSkills
call SetupSpells


call SwitchToWoW

call DoTrain
call Logout

Stop